LibrettoM3(リカバリ編)

LibM3のHDDリカバリ方法

HDD換装したり、OSを再インストールしなければならない場合、LibrettoM3の場合付属のリカバリCDでのOSインストールとなります。
しかしLibM3ではちょっと困ったことになります。LibM3はFDDがUSBだし、PCMCIA SLOTがひとつしかなく、一般的なFDDとSCSI CD-ROMをつなげてBootということは出来ません。マニュアルにはCD-ROMブートできるCD-ROMドライブが必要となっています。
私の場合、家ではLibをLAN接続して使っているのでLibにCD-ROMが必要ということはありません。普段必要ないのに、インストールのためだけにわざわざCD-ROMブート出来るCD-ROMドライブを買いたくありませんね。

どうやってやったらいいの？

NiftyやWebで調べたら、警備員コスナーさんのホームページに情報がありました。調査中とのことでしたが、Boot可能なCD-ROMを使わずにOSリカバリできるらしいということだったので試してみました。デスクトップでリカバリをするという方法です。この方法でうまくリカバリできましたので紹介します。

下準備

今回行うのは、2.1GBのMK2110MATを4.3GBのMK4309MATへ換装です。まずは、MK4309MATのFIDKから。
2.5'->3.5'変換ブラケットを使ってMK4309MATをデスクトップマシンにつけます。デスクトップマシンで使っているwin98の起動ディスクでMK4309MATのFDISKをします。今回は4.3GB全部をFAT32で一区画にすることにしました。

それから起動ディスク用のFDDをフォーマットして用意しておきます。

起動ディスク作成

次に本題の起動ディスクの作成。起動ディスクもデスクトップで作っちゃいました。デスクトップとLibM3はLANでつながっているのでこうなったわけですが、LibrettoのFDDを接続して作業してもいいと思います。

LibrettoM3のC:\TOSSETというディレクトリに入っている FILE2FD.COM というプログラムと、リカバリCD内の BOOTIMG.BIN をコピーして、同じディレクトリにおいてDOS窓を開きます。フォーマット済のFDDをドライブに入れて、

> FILE2FD BOOTIMG.BIN

と入力して実行すると、FDDに起動ディスクを作成します。

注意！ M3のHDD(換装前HDD)をフォーマットする前にFILE2FD.COMはバックアップしておきましょう。

起動ディスク修正

次に起動ディスクの修正。デスクトップで使用するCD-ROMドライバとMSCDEX.EXEが必要になるので、それを起動フロッピにコピーします。それからautoexec.batとconfig.sysを修正します。

ファイルのコピー
起動フロッピにコピーするファイル

ATAPI_CD.SYS(私のPCの場合)

MSCDEX.EXE

ファイルの修正
autoexec.batとconfig.sysを修正します。以下のように修正しました。
デスクトップのCD-ROMドライブが使えるようにする修正と、autoexec.batの3,4行目をコメントにする修正です。

config.sys

DEVICE=A:\DOS\HIMEM.SYS /TESTMEM:OFF
DEVICE=A:\DOS\EMM386.EXE RAM NOEMS
DEVICE=A:\DOS\ANSI.SYS
rem DEVICE=A:\TOOLS\TOSCDROM.SYS /D:TSCD001 /A
DEVICE=ATAPI_CD.SYS /S:1 /D:MSCD001

FILES=40
DOS=HIGH,UMB
LASTDRIVE=Z
SWITCHES=/F
SHELL=A:\COMMAND.COM A:\ /P /E:2048

autoexec.bat

@ECHO OFF
PATH=A:\TOOLS;A:\DOS
rem ID
rem IF ERRORLEVEL 1 OFF

REM --- SINGLE98 Ver 1.01.98N ---
REM --- TOSCDROM.SYS Ver.3.21P ---


MBR /G1 >NUL
IF ERRORLEVEL 1 GOTO 2ND

:MENU
REM 復元しますか？
BMPVIEW A:\BMP\RECOVERY.BMP /X=140 /Y=160
CLK
CHOICE > NUL
IF ERRORLEVEL 2 GOTO CDERREND
BMPVIEW /XC A:\BMP\Y2.BMP /X=340 /Y=288

BMPVIEW A:\BMP\MES002.BMP /X=140 /Y=160
CLK
CHOICE > NUL
IF ERRORLEVEL 2 GOTO CDERREND
BMPVIEW A:\BMP\Y1.BMP /XC /X=340 /Y=288
MBR /S1:01 >NUL

:2ND
CDCKBOOT > NUL
IF ERRORLEVEL 1 SETBOOT 0 >NUL
MBR /P >NUL
IF ERRORLEVEL 11 GOTO FORMAT
IF ERRORLEVEL 10 GOTO FORMAT
IF ERRORLEVEL  7 GOTO FORMAT
IF ERRORLEVEL  6 GOTO FORMAT
IF ERRORLEVEL  1 GOTO CLEAR
GOTO FDISK

:CLEAR
MBR /! >NUL
CDCKBOOT > NUL
IF ERRORLEVEL 1 SETBOOT 4 >NUL
HARDBOOT

:FDISK
FDISK 1 /PRI:65535
IF ERRORLEVEL 1 GOTO FDISKERR
CDCKBOOT > NUL
IF ERRORLEVEL 1 SETBOOT 4 >NUL
HARDBOOT

:FORMAT
CLS
FORMAT C: /U /V:"" < A:\TOOLS\YENT
MBR /C1 >NUL
GOTO GO

:GO
SMARTDRV
rem MSCDEX /D:TSCD001 /L:T >NUL
MSCDEX.EXE /D:MSCD001 /L:d >nul
IF ERRORLEVEL 1 GOTO NO_CDDRV

:CHECKCD
CDCHECK d: > NUL
CDCHECK d: > NUL
IF ERRORLEVEL 2 GOTO NO_CDDRV
IF ERRORLEVEL 1 GOTO SET_CDROM
SET CDDRV=d:
GOTO CD_EXIST

:SET_CDROM
REM CDを入れてください。
BMPVIEW A:\BMP\SETCDROM.BMP
PAUSE > NUL

:CHECKCD2
CDCHECK d: > NUL
CDCHECK d: > NUL
IF ERRORLEVEL 2 GOTO NO_CDDRV
IF ERRORLEVEL 1 GOTO NOCDROM
SET CDDRV=d:
GOTO CD_EXIST

:CD_EXIST
IF NOT EXIST %CDDRV%\SETENV98.BAT GOTO BAD_CDROM

:RECOVERY
BMPVIEW A:\BMP\SETUP.BMP /X=136 /Y=160
CALL %CDDRV%\SETENV98.BAT
CD C:\
F3D %CDDRV%\%FILENAME% C: %F3DOPT% /P:20,18,40,1
IF ERRORLEVEL 1 GOTO F3D_NG
C:\WINDOWS\COMMAND\SYS C:\WINDOWS C: >NUL
LABEL C:%VOLLABEL%

BMPVIEW A:\BMP\THEEND.BMP
SMARTDRV /C
rem --- CDX /E
:LOOP
PAUSE > NUL
GOTO LOOP

REM ================= ERROR ===============================
:BAD_CDROM
REM CD-ROMが違います。
BMPVIEW A:\BMP\BADCDROM.BMP /X=140 /Y=160
CLK
CHOICE > NUL
IF ERRORLEVEL 2 GOTO CDERREND
BMPVIEW A:\BMP\Y1.BMP /XC /X=340 /Y=288
GOTO CHECKCD2

:NOCDROM
REM CD-ROMを認識できません。
BMPVIEW A:\BMP\NOCDROM.BMP /X=140 /Y=160
CLK
CHOICE > NUL
IF ERRORLEVEL 2 GOTO CDERREND
BMPVIEW A:\BMP\Y1.BMP /XC /X=340 /Y=288
GOTO CHECKCD2

:NO_CDDRV
REM CD-ROMドライブが見つかりません。
BMPVIEW A:\BMP\NO_CDDRV.BMP
PAUSE > NUL
GOTO END

:F3D_NG
SMARTDRV /C
BMPVIEW A:\BMP\RECOVERR.BMP /X=96 /Y=168
CLK
CHOICE > NUL
IF ERRORLEVEL 2 GOTO R_ERREND
BMPVIEW A:\BMP\Y3.BMP /XC /X=392 /Y=272
BMPVIEW A:\BMP\REBOOT2.BMP
PAUSE > NUL
CDCKBOOT > NUL
IF ERRORLEVEL 1 SETBOOT 4 >NUL
HARDBOOT

:R_ERREND
BMPVIEW A:\BMP\N_PBTN.BMP /XC /X=464 /Y=272
GOTO END

:CDERREND
BMPVIEW A:\BMP\N1.BMP /XC /X=412 /Y=288
GOTO END

:FDISKERR
ECHO FDISK ERROR!
GOTO END

:END
SMARTDRV /C
OFF

リカバリ作業

作成した起動ディスクFDDとリカバリCDとMK4309MATをデスクトップマシンにセットして再起動。自動的にリカバリプログラムが起動してリカバリ作業ができます。

デスクトップでの復元作業の様子です。

PCを起動すると自動的にこの画面になります。あとは画面にしたがって進めるだけです。

警告画面です。
ハードディスクの内容が失われます。

CD-ROMを入れて何かキーを押します。

ソフト復元中の画面です。ちょっと時間かかります。

ソフトの復元が終了したら、再起動するように言われますが、デスクトップマシンでの作業はここまでなので再起動ではなく電源を切ります。
これでLibM3に最初に電源を入れる時のHDDの状態になりました。この状態でHDDをLibM3に移植します。

HDD換装

HDDの入れ替えです。Lib30の時はHDD交換は簡単に出来ましたが、LibM3は分解が必要で面倒です。
入れ替え作業は、警備員コスナーさんのホームページを参考にさせていただき作業しました。各段階の写真を掲載されていますので分かりやすいです。

HDD換装完了

無事HDD入れ替えが出来たらLibM3の電源を入れます。購入時、最初に電源を入れたときと同じようにwindows98のセットアップが始まります。
これでめでたくHDD換装ができました。

システムアップデート

リカバリ後は、システムアップデートディスクを使ってシステムアップデートをしておきましょう。

>MNUpdate.bat

>PMUpdate.bat

この二つを実行すればOKです。